Kowsi KWS-X1 USB-C PD QC Tester Firmware V1.0.5V

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"

set "IMAGE=firmware.X1C"
set "FLASHER=flasher.exe"

echo ============================================================
echo  Rust Firmware-Flasher  -  %IMAGE%
echo ============================================================
echo Disclaimer. This is unofficial firmware, provided as is, without warranty of any kind.
echo Flashing it, and using the meter with it, is entirely at your own risk. The author
echo is not responsible for any damage to the meter, to chargers, cables or connected
echo devices, or for any other loss. Sink mode can put up to the charger's highest
echo voltage on the meter's output.
echo.

if not exist "%FLASHER%" (
    echo ERROR: %FLASHER% not found.
    echo Folder: %CD%
    goto :abort
)
if not exist "%IMAGE%" (
    echo ERROR: %IMAGE% not found.
    echo Folder: %CD%
    goto :abort
)

echo [1/4] Computing SHA-256 of the firmware and confirming it
set "HASH="
for /f "usebackq delims=" %%a in (`powershell -NoProfile -Command "(Get-FileHash -LiteralPath '%IMAGE%' -Algorithm SHA256).Hash.ToLower()"`) do set "HASH=%%a"

if not defined HASH (
    echo ERROR: Could not compute the hash.
    goto :abort
)

set "TAIL=!HASH:~63,1!"
if "!TAIL!"=="" echo     WARNING: Value does not have the expected length of 64 characters.
echo     Local firmware hash : !HASH!
echo     Now compare this value yourself against the independently confirmed hash
echo     - release page, signature, or a second machine.
echo.
set /p "CONFIRM=Does the hash match? (y/n): "
if /i not "!CONFIRM!"=="y" (
    echo.
    echo ERROR: Hash not confirmed - no flashing.
    echo        Get the firmware again from github.com/kralonur/kws-x1-standalone-rs/releases
    goto :abort
)
echo     OK - hash confirmed as correct.
echo.

echo [2/4] Offline validation - dry run, no device access
"%FLASHER%" --dry-run --image "%IMAGE%" --confirm-sha256 "!HASH!"
if errorlevel 1 (
    echo.
    echo ERROR: Validation failed. Aborting.
    goto :abort
)
echo     Validation successful.
echo.

echo [3/4] Put the device into bootloader mode
echo     - Unplug the meter from USB
echo     - Hold BACK and OK pressed at the same time
echo     - Plug the meter in while holding them
echo     - Do NOT connect an output load
echo.
pause

echo     Optional mode check - mode 0 means bootloader:
"%FLASHER%" --info
echo.

echo [4/4] Writing the firmware
echo     CAUTION: This writes to the device.
set /p "GO=Flash now? (y/n): "
if /i not "!GO!"=="y" (
    echo     Cancelled. Nothing was written.
    goto :end
)
echo.
"%FLASHER%" --image "%IMAGE%" --confirm-sha256 "!HASH!"
if errorlevel 1 (
    echo.
    echo ERROR while writing or verifying.
    echo Leave the device in bootloader mode and investigate the cause.
    goto :abort
)
echo.
echo Leave the device connected. The backlight flashes briefly with a blank display,
echo then the meter restarts and the process is complete.
goto :end

:abort
echo.
echo Process aborted.

:end
echo.
pause
endlocal